Imixs/office-alexander-logistics
3
1
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions

sepa Neue Bank in Polen - bankmillennium

Browse source
This commit is contained in:
Ralph Soika 2025-04-05 15:21:05 +02:00
parent 1db1cd756c
commit b9084965e0
3 changed files with 233 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

17
office-alexander-logistics-app/src/test/java/com/alexanderlogistics/sepa/TestSEPATransform.java
View file

@ -62,4 +62,21 @@ public class TestSEPATransform {
} }
} }
/**
* XSL Transformation for SEPA file for Bank Polski
*
* Neue Bank in Polen - bankmillennium
*
* @throws IOException
*/
@Test
public void testBankPolskibankmillennium() throws IOException {
String MODEL_PATH_XML = "sepa/beispiel-daten.xml";
String MODEL_PATH_XSL = "sepa/sepa-2.0.11-pl_bankmillennium.xsl";
try {
XSLTester.transform(MODEL_PATH_XML, MODEL_PATH_XSL, "../reports/sepa/result_sepa-pl_bankmillennium.xml");
} catch (Exception e) {
fail();
}
}
} }

6
reports/sepa/beispiel-daten.xml
View file

@ -82,6 +82,9 @@
<item name="invoice.currency"> <item name="invoice.currency">
<value xsi:type="xs:string">EUR</value> <value xsi:type="xs:string">EUR</value>
</item> </item>
<item name="invoice.country">
<value xsi:type="xs:string">DE</value>
</item>
<item name="invoice.date"> <item name="invoice.date">
<value xsi:type="xs:dateTime">2020-07-07T00:00:00+02:00</value> <value xsi:type="xs:dateTime">2020-07-07T00:00:00+02:00</value>
</item> </item>
@ -135,6 +138,9 @@
<item name="invoice.currency"> <item name="invoice.currency">
<value xsi:type="xs:string">EUR</value> <value xsi:type="xs:string">EUR</value>
</item> </item>
<item name="invoice.country">
<value xsi:type="xs:string">IT</value>
</item>
<item name="invoice.date"> <item name="invoice.date">
<value xsi:type="xs:dateTime">2020-07-07T00:00:00+02:00</value> <value xsi:type="xs:dateTime">2020-07-07T00:00:00+02:00</value>
</item> </item>

210
reports/sepa/sepa-2.0.11-pl_bankmillennium.xsl Normal file
View file

@ -0,0 +1,210 @@
<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
version="2.0">
<xsl:strip-space elements="*" />
<xsl:output method="xml" indent="yes" encoding="UTF-8" standalone="yes" />
<xsl:template match="/">
<xsl:variable name="now" select="current-dateTime()" />
<Document
xmlns="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
xsi:schemaLocation="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03 pain.001.001.03.xsd">
<CstmrCdtTrfInitn>
<!-- generate header info -->
<!-- compute count of invoices -->
<xsl:variable name="count"
select="count(/data/document[starts-with(normalize-space(item[@name = '$modelversion']/value),'rechnungseingang')]/item[@name='$uniqueid']/value)" />
<!-- compute total amount -->
<xsl:variable name="totalsum"
select="xs:decimal(sum(/data/document[starts-with(normalize-space(item[@name = '$modelversion']/value),'rechnungseingang')]/item[@name='invoice.total']/value))" />
<!-- round to 2 digits -->
<xsl:variable name="total"
select="format-number(xs:decimal(round-half-to-even($totalsum, 2)), '0.00')" />
<!-- shortcut for the sepa export document -->
<xsl:variable name="exportWorkitem"
select="/data/document[normalize-space(item[@name = '$workflowgroup']/value) = 'SEPA-Export']" />
<GrpHdr>
<MsgId>
<xsl:value-of
select="replace($exportWorkitem/item[@name='$uniqueid']/value, '-', '')" />
</MsgId>
<CreDtTm>
<xsl:value-of
select="format-dateTime($now, '[Y0001]-[M01]-[D01]T[H01]:[m01]:[s01]')" />
</CreDtTm>
<NbOfTxs>
<xsl:value-of select="$count" />
</NbOfTxs>
<CtrlSum>
<!-- round to 2 digits -->
<xsl:value-of select="$total" />
</CtrlSum>
<InitgPty>
<Nm>
<xsl:value-of
select="$exportWorkitem/item[@name='dbtr.name']/value" />
</Nm>
</InitgPty>
</GrpHdr>
<PmtInf>
<PmtInfId>
<xsl:value-of
select="replace($exportWorkitem/item[@name='$uniqueid']/value, '-', '')" />
<xsl:text>-1</xsl:text>
</PmtInfId>
<PmtMtd>TRF</PmtMtd>
<NbOfTxs>
<xsl:value-of select="$count" />
</NbOfTxs>
<CtrlSum>
<!-- round to 2 digits -->
<xsl:value-of select="$total" />
</CtrlSum>
<PmtTpInf>
<SvcLvl>
<Cd>SEPA</Cd>
</SvcLvl>
</PmtTpInf>
<ReqdExctnDt>
<xsl:value-of
select="format-dateTime($now, '[Y0001]-[M01]-[D01]')" />
</ReqdExctnDt>
<Dbtr>
<Nm>
<xsl:value-of
select="$exportWorkitem/item[@name='dbtr.name']/value" />
</Nm>
</Dbtr>
<DbtrAcct>
<Id>
<IBAN>
<xsl:value-of
select="replace($exportWorkitem/item[@name='dbtr.iban']/value, ' ', '')" />
</IBAN>
</Id>
</DbtrAcct>
<DbtrAgt>
<FinInstnId>
<BIC>
<xsl:value-of
select="replace($exportWorkitem/item[@name='dbtr.bic']/value, ' ', '')" />
</BIC>
</FinInstnId>
</DbtrAgt>
<!--
SHAR – Charges are shared between debtor and creditor
SLEV – Charges are handled according to service level
-->
<ChrgBr>SHAR</ChrgBr>
<!-- generate CdtTrfTxInf for each invoice -->
<xsl:apply-templates
select="/data/document[starts-with(normalize-space(item[@name = '$modelversion']/value),'rechnungseingang')]" />
</PmtInf>
<Purp>
<Prtry>FRGN</Prtry>
</Purp>
</CstmrCdtTrfInitn>
</Document>
</xsl:template>
<!-- This template builds sepa header info -->
<xsl:template
match="/data/document[normalize-space(item[@name = '$workflowgroup']/value) = 'SEPA-Export']">
<!-- not in use -->
</xsl:template>
<!-- This template builds sepa payment info for each invoice -->
<xsl:template
match="/data/document[starts-with(normalize-space(item[@name = '$modelversion']/value),'rechnungseingang')]">
<!-- round to 2 digits - geht nur mit sum funktion -->
<xsl:variable
name="wert2"
select="format-number(xs:decimal(round-half-to-even(item[@name='invoice.total']/value, 2)), '0.00')" />
<CdtTrfTxInf
xmlns="urn:iso:std:iso:20022:tech:xsd:pain.001.001.03">
<PmtId>
<EndToEndId>NOTPROVIDED</EndToEndId>
</PmtId>
<Amt>
<InstdAmt>
<xsl:attribute name="Ccy"><xsl:value-of
select="item[@name='invoice.currency']/value" /></xsl:attribute>
<!-- round to 2 digits -->
<xsl:value-of select="$wert2" />
</InstdAmt>
</Amt>
<CdtrAgt>
<FinInstnId>
<BIC>
<xsl:value-of select="replace(item[@name='cdtr.bic']/value, ' ', '')" />
</BIC>
</FinInstnId>
</CdtrAgt>
<Cdtr>
<!-- MAX70 -->
<Nm>
<!-- <xsl:value-of select="substring(item[@name='cdtr.name']/value, 1, 70)" /> -->
<!-- entfernen der non ascii zeichen
<xsl:value-of
select="substring(replace(item[@name='cdtr.name']/value, '\P{IsBasicLatin}', ''), 1, 70)" />
-->
<xsl:value-of
select="substring(translate(
normalize-space(item[@name='cdtr.name']/value),
translate(item[@name='cdtr.name']/value, 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789 /-?:().,''+''{}.', ''),''), 1, 70)" />
</Nm>
<PstlAdr>
<Ctry>
<xsl:choose>
<xsl:when test="not(item[@name='invoice.country'])">PL</xsl:when>
<xsl:when test="item[@name='invoice.country']/value = ''">PL</xsl:when>
<xsl:otherwise>
<xsl:value-of select="item[@name='invoice.country']/value" />
</xsl:otherwise>
</xsl:choose>
</Ctry>
</PstlAdr>
</Cdtr>
<CdtrAcct>
<Id>
<IBAN>
<xsl:value-of select="replace(item[@name='cdtr.iban']/value, ' ', '')" />
</IBAN>
</Id>
</CdtrAcct>
<RmtInf>
<!-- Max140Text -->
<Ustrd>
<xsl:variable name="sequenceNumber" select="item[@name='sequencenumber']/value" />
<xsl:variable name="invoiceNumber" select="item[@name='invoice.number']/value" />
<xsl:variable name="combinedInfo">
<xsl:value-of select="$sequenceNumber" />
<xsl:if
test="$sequenceNumber != '' and $invoiceNumber != ''">/</xsl:if>
<xsl:value-of
select="$invoiceNumber" />
</xsl:variable>
<xsl:value-of
select="substring(translate(
normalize-space($combinedInfo),
translate($combinedInfo, 'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789 /-?:().,''+''{}.', ''),''), 1, 140)" />
</Ustrd>
</RmtInf>
</CdtTrfTxInf>
</xsl:template>
</xsl:stylesheet>